GenAsm (language)

The genAsm assembly language is a low-level dataflow language for writing programs to be executed on the Mill processors. The language is accepted by the genAsm assembler, which create ELF files suitable as input to the prelinker or specializer. The assembler is intended for use when high-level language compilers are unable to provide a desired access to Mill hardware facilities.

Syntax in EBNF:

Terminal keywords and symbols are in quotes Meta-symbols are bold

  ::=       is defined as
  |         alternatives
  [ ... ]   option (zero or one times
  { ... }   repetition (zero or more times)
  ,         sequence (in order left-to-right)
  ;         end of definition
  

   program        ::=  "module", identifier, expDefs;
   expDefs        ::=  expDef, {";", expDef};
   expDef         ::=  expression | definition;
   definition     ::=  functionDef;
   functionDef    ::=  "func", identifier, formals, [results], "{", expDefs, "}";
   formals        ::=  "(", [formal, {",", formal}], ")";
   formal         ::=  widthTag, identifier;
   widthTag       ::=  "b" | "h" | "w" | "d" | "q" | "bv" | "hv" | "wv" | "dv" | "qv";
   results        ::=  "->", widthTag |
                       "->", "(", [widthTag, {",", widthTag}], ")";
   expression     ::=  [secondary] | 
                       expression, binding | 
                       expression, opId, [secondary] |
                       expression, "?", expression, ":", expression;
   secondary      ::=  primary | 
                       secondary, "(", [expression, {",", expression}], ")";
   primary        ::=  widthTag |
                       [widthTag, ":"] number  | 
                       boundId | 
                       funcId | 
                       opId |
                       "(" expression ")";
   binding        ::=  "-:" identifier | 
                       "-:" "{", identifier, {",", identifier}, "}";
   opId           ::=  identifier
   boundId        ::=  identifier
   funcId         ::=  identifier
   identifier     ::=  alpha, {alnum}
   alpha          ::=  "_" | <"a"-"z"> | <"A"-"Z">
   digit          ::=  <"0"-"9">
   alnum          ::=  digit | alpha
   comment        ::=  "//", {<char>}, <EOL> | "/*", {<char>}, "*/"