Difference between revisions of "GenAsm (language)"
From Mill Computing Wiki
m (Missing an 'or' vertical bar in the 'secondary' definition) | m (Add missing commas between concatenated terms) | ||
| Line 36: | Line 36: | ||
secondary, widthPack; | secondary, widthPack; | ||
primary ::= widthTag | | primary ::= widthTag | | ||
| − | [widthTag, ":"] number | | + | [widthTag, ":"], number | |
boundId | | boundId | | ||
ebbId | | ebbId | | ||
| Line 44: | Line 44: | ||
"begin", serial, "end" | | "begin", serial, "end" | | ||
ifClause; | ifClause; | ||
| − | binding ::= "-:" identifier | | + | binding ::= "-:", identifier | |
"-:", idenPack; | "-:", idenPack; | ||
idenPack ::= "{", identifier, {",", identifier}, "}"; | idenPack ::= "{", identifier, {",", identifier}, "}"; | ||
| − | gang ::= opId ["." opId]; | + | gang ::= opId, [".", opId]; |
opId ::= identifier; | opId ::= identifier; | ||
ebbId ::= identifier; | ebbId ::= identifier; | ||
| Line 71: | Line 71: | ||
hexDigit ::= decDigit | <"a"-"f"> | <"A"-"F">; | hexDigit ::= decDigit | <"a"-"f"> | <"A"-"F">; | ||
float ::= decimal, ".", [decimal], [exponent] | | float ::= decimal, ".", [decimal], [exponent] | | ||
| − | decimal, ["." [decimal]], exponent; | + | decimal, [".", [decimal]], exponent; |
exponent ::= "e", [sign], decimal | | exponent ::= "e", [sign], decimal | | ||
"E", [sign], decimal; | "E", [sign], decimal; | ||
sign ::= "+" | "-"; | sign ::= "+" | "-"; | ||
comment ::= "//", {<char>}, <EOL> | "/*", {<char>}, "*/"; | comment ::= "//", {<char>}, <EOL> | "/*", {<char>}, "*/"; | ||
Revision as of 18:41, 6 January 2015
The genAsm assembly language is a low-level dataflow language for writing programs to be executed on the Mill processors. The language is accepted by the genAsm assembler, which create ELF files suitable as input to the prelinker or specializer. The assembler is intended for use when high-level language compilers are unable to provide a desired access to Mill hardware facilities.
Syntax in EBNF:
" ... " terminal keyword or symbol
::= is defined as
| alternatives
[ ... ] option (zero or one times
{ ... } repetition (zero or more times)
, sequence (in order left-to-right)
; end of definition
program ::= "module", moduleId, serial;
serial ::= [expDef], {";", [expDef]};
expDef ::= expression |
definition |
join, [expDef];
definition ::= functionDef | labelDef;
functionDef ::= ["inline"], "func", identifier, formals, [results], funcBody;
funcBody ::= ":", expression | "outcall" | "forward";
formals ::= "(", [formal, {",", formal}], ")";
formal ::= widthTag, identifier;
widthTag ::= "b" | "h" | "w" | "d" | "q" | "bv" | "hv" | "wv" | "dv" | "qv";
results ::= widthPack;
widthPack ::= "{", [widthTag, {",", widthTag}], "}";
labelDef ::= "label", [widthPack], identifier, "forward";
expression ::= secondary |
expression, binding |
expression, gang, [secondary] |
expression, ["inline"], funcId, [secondary] |
expression, join |
expression, "?", expression, ":", expression;
secondary ::= primary |
secondary, "(", [expression, {",", expression}], ")" |
secondary, widthPack;
primary ::= widthTag |
[widthTag, ":"], number |
boundId |
ebbId |
["inline"], funcId |
gang |
"(", expression, ")" |
"begin", serial, "end" |
ifClause;
binding ::= "-:", identifier |
"-:", idenPack;
idenPack ::= "{", identifier, {",", identifier}, "}";
gang ::= opId, [".", opId];
opId ::= identifier;
ebbId ::= identifier;
join ::= ebbId, ":";
ifClause ::= "if", predPart, thenPart, {elifPart}, [elsePart], "fi";
predPart ::= serial;
thenPart ::= "then", serial;
elifPart ::= "elif", serial;
elsePart ::= "else", serial;
boundId ::= identifier;
funcId ::= identifier;
moduleId ::= identifier;
identifier ::= [qualification], name;
qualification ::= [qualification], name, "::";
name ::= alpha, {alnum};
alnum ::= decDigit | alpha;
alpha ::= "_" | <"a"-"z"> | <"A"-"Z">;
decDigit ::= <"0"-"9">;
number ::= decimal | hexadecimal | float;
decimal ::= digit, { digit };
hexadecimal ::= hexBase, hexDigit, { hexDigit };
hexBase ::= "0x" | "0X";
hexDigit ::= decDigit | <"a"-"f"> | <"A"-"F">;
float ::= decimal, ".", [decimal], [exponent] |
decimal, [".", [decimal]], exponent;
exponent ::= "e", [sign], decimal |
"E", [sign], decimal;
sign ::= "+" | "-";
comment ::= "//", {<char>}, <EOL> | "/*", {<char>}, "*/";
