Difference between revisions of "GenAsm (language)"

Revision as of 03:08, 28 September 2014

The genAsm assembly language is a low-level dataflow language for writing programs to be executed on the Mill processors. The language is accepted by the genAsm assembler, which create ELF files suitable as input to the prelinker or specializer. The assembler is intended for use when high-level language compilers are unable to provide a desired access to Mill hardware facilities.

Syntax in EBNF:

  " ... "   terminal keyword or symbol
  ::=       is defined as
  |         alternatives
  [ ... ]   option (zero or one times
  { ... }   repetition (zero or more times)
  ,         sequence (in order left-to-right)
  ;         end of definition
  

   program        ::=  "module", identifier, expDefs;
   serial         ::=  [expDef, {";", expDef}];
   expDef         ::=  expression | definition;
   definition     ::=  functionDef;
   functionDef    ::=  ["inline"], "func", identifier, formals, [results], funcBody;
   funcBody       ::=  ":", expression | "outcall" | "forward";
   formals        ::=  "(", [formal, {",", formal}], ")";
   formal         ::=  widthTag, identifier;
   widthTag       ::=  "b" | "h" | "w" | "d" | "q" | "bv" | "hv" | "wv" | "dv" | "qv";
   results        ::=  "->", widthTag |
                       "->", "(", [widthTag, {",", widthTag}], ")";
   expression     ::=  [secondary] | 
                       expression, binding | 
                       expression, gang, [secondary] |
                       expression, ["inline"], funcId, [secondary]
                       expression, "?", expression, ":", expression;
   secondary      ::=  primary | 
                       secondary, "(", [expression, {",", expression}], ")";
   primary        ::=  widthTag |
                       [widthTag, ":"] number  | 
                       boundId | 
                       ["inline"], funcId | 
                       gang |
                       "(" expression ")" |
                       "begin", serial, "end" |
                       ifClause;
   binding        ::=  "-:" identifier | 
                       "-:" "{", identifier, {",", identifier}, "}";
   gang           ::=  opId ["." opId];
   opId           ::=  identifier;
   ifClause       ::=  "if", predPart, thenPart, {elifPart}, [elsePart], "fi";
   predPart       ::=  serial;
   thenPart       ::=  "then", serial;
   elifPart       ::=  "elif", serial;
   elsePart       ::=  "else", serial;
   boundId        ::=  identifier;
   funcId         ::=  identifier;
   identifier     ::=  alpha, {alnum};
   alnum          ::=  decDigit | alpha;
   alpha          ::=  "_" | <"a"-"z"> | <"A"-"Z">;
   decDigit       ::=  <"0"-"9">;
   number         ::=  decimal | hexadecimal | float;
   decimal        ::=  digit, { digit };
   hexadecimal    ::=  hexBase, hexDigit, { hexDigit }
   hexBase        ::=  "0x" | "0X"
   hexDigit       ::=  decDigit | <"a"-"f"> | <"A"-"F">
   float          ::=  decimal, ".", [decimal], [exponent] |
                       decimal, ["." [decimal]], exponent
   exponent       ::=  "e", [sign], decimal |
                       "E", [sign], decimal
   sign           ::=  "+" | "-"
   comment        ::=  "//", {<char>}, <EOL> | "/*", {<char>}, "*/";